Easy way to switch between two windows of the same app in Windows 10

Question

I am looking for a way to switch between two open windows of the same app with a key shortcut, I have found this https://neosmart.net/EasySwitch/ but it is not open source and I don't trust it even works. Does anyone has an alternative ? This is OOTB in Unity and Mac OS it is absurd that Windows doesn't have it.

Some time ago a Microsoft employee made this tool : https://switcher.en.softonic.com/ not sure what is the official website, it is GREAT but works only on Windows 7 and doesnt work on 10, also not open source.

The closest thing I have found that is open source is this one https://github.com/JochenBaier/fastwindowswitcher but is less then ideal.

is there an alternative ?

Answer 1

You may implement the Alt+` shortcut yourself using the free AutoHotkey.

The following script will cycle through all the windows of the active process:

!`::
WinGetClass, OldClass, A
WinGet, ActiveProcessName, ProcessName, A
WinGet, WinClassCount, Count, ahk_exe %ActiveProcessName%
IF WinClassCount = 1
    Return
loop, 2 {
  WinSet, Bottom,, A
  WinActivate, ahk_exe %ActiveProcessName%
  WinGetClass, NewClass, A
  if (OldClass <> "CabinetWClass" or NewClass = "CabinetWClass")
    break
}

After installing AutoHotKey, put the above text in a .ahk file and double-click it to test. You may stop the script by right-click on the green H icon in the traybar and choosing Exit. To have it run on login, place it in the Startup group at
C:\Users\USER-NAME\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup.

Useful AutoHotkey documentation:

• List of Keys
• Hotkeys

Answer 2

There are three ways for doing this:

1. You can hold Ctrl + Click on the icon of the app in the taskbar
2. Use Win + position of app on taskbar. For example, if Google Chrome is on third position, do Win+3 to switch between windows of Chrome. Note that this cycles through the different windows, so for opening 4th window you'll have to press 3 four times.
3. The fastest of all, Using Win + ctrl + n does exactly what you want. (where n is position of the app on taskbar)

Note that in 2nd and 3rd options if n is specified such that no window of that program is already open, windows will open a new window. This effect can also be acheived by pressing Win + shift + n, regardless of if windows of that app were already open or not.

Answer 3

I've updated the script of harrymc to be executable in AutoHotkey v2:

#Requires AutoHotkey v2.0

!`::{
  OldClass := WinGetClass("A")
  ActiveProcessName := WinGetProcessName("A")
  WinClassCount := WinGetCount("ahk_exe" ActiveProcessName)
  IF WinClassCount = 1
      Return
  loop 2 {
    WinMoveBottom("A")
    WinActivate("ahk_exe" ActiveProcessName)
    NewClass := WinGetClass("A")
    if (OldClass != "CabinetWClass" or NewClass = "CabinetWClass")
      break
  }
}

From this it should also be easy to convert the script of EugeneK.

I tried to implement EugeneK's script as well in v2. I'm not sure if it has all the intended features, but it works fine and will be what I'll be using

#Requires AutoHotkey v2.0

!`::
{
    win_id := WinActive("A")
    win_class := WinGetClass("A")
    active_process_name := WinGetProcessName("A")
    ; We have to be extra careful about explorer.exe since that process is responsible for more than file explorer
    if (active_process_name = "explorer.exe")
        win_list := WinGetList("ahk_exe" active_process_name " ahk_class" win_class)
    else
        win_list := WinGetList("ahk_exe" active_process_name)
    
    ; Calculate index of next window. Since activating a window puts it at the top of the list, we have to take from the bottom.
    next_window_i := win_list.Length
    next_window_id := win_list[next_window_i]
    
    ; Activate the next window and send it to the top.
    WinMoveTop("ahk_id" next_window_id)
    WinActivate("ahk_id" next_window_id)
}

In addition: I like having this functionality tied to the key Alt + |. So, in case you also like this better, change !':: to !|::.

Answer 4

I've modified ahk script in order to have an Ubuntu style switching. Pressing ` while holding an alt key will cycle through all application windows putting the next one on top rather than sending top window to the bottom. And single alt + ` combinations will cycle between last two windows.

!`::
WinGet, ActiveProcessName, ProcessName, A
WinGet, WinClassCount, List, ahk_exe %ActiveProcessName%

if (WinClassCount = 1)
    return

if (NextWindow = "")
    NextWindow := 2

element := % WinClassCount%NextWindow%

WinSet, Top,, ahk_id %element%
WinActivate, ahk_id %element%

NextWindow += 1

if (NextWindow > WinClassCount || !getKeyState("Alt"))
    NextWindow := 2

return

Answer 5

I've implemented a script using AutoHotkey v2 which does what Ubuntu can do out of the box: switch between windows of the current app by pressing Alt+; (which is what the key in the top left corner types by default on my keyboard layout; you will probably want to adjust for yourself).
It counts with multiple presses so works even in cases there are multiple windows of the app, not just two. Feel free to use, PRs for improving welcome :-D

https://github.com/jendakol/autohotkey/blob/main/window-switch-multiple.ahk

Current version:

!;::
{
    static LastRun := 0
    static QuickPress := 0

    Now := A_TickCount

    if (Now - LastRun < 400)
        QuickPress++
    else
        QuickPress := 0

    OutputDebug '`n`nNow: ' Now ' LastRun: ' LastRun ' QuickPress: ' QuickPress '`n'



    OldClass := WinGetClass("A")
    ActiveProcessName := WinGetProcessName("A")
    WinClassCount := WinGetCount("ahk_exe " ActiveProcessName)
    ActiveId := WinGetID("A")
    OutputDebug 'Current:    ' ActiveId '/' OldClass '/' ActiveProcessName '/' WinGetTitle("ahk_id" ActiveId) "`n"

    if (WinClassCount = 1)
        Return

    ToSkip := QuickPress
    OutputDebug 'Will skip ' ToSkip ' of ' WinClassCount '`n'

    ids := WinGetList("ahk_exe " ActiveProcessName)
    for SiblingId in ids {
        if (WinGetClass("ahk_id" SiblingId) != OldClass)
            continue

        OutputDebug 'Found:      ' SiblingId '/' WinGetClass("ahk_id" SiblingId) '/' WinGetProcessName("ahk_id" SiblingId) '/' WinGetTitle("ahk_id" SiblingId) '`n'

        if (SiblingId != ActiveId && ToSkip-- <=0) {
            OutputDebug 'Switch to:  ' SiblingId '/' WinGetClass("ahk_id" SiblingId) '/' WinGetProcessName("ahk_id" SiblingId) '/' WinGetTitle("ahk_id" SiblingId) '`n'
            WinActivate("ahk_id" SiblingId)
            break
        }
    }


    LastRun := A_TickCount
}